Query a Vector Index

Querying with Embeddings

When querying a vector index, you have to query with an embedding.

For example, you want to use the vector index to find questions similar to the text "What are examples of good open-source projects?". You would first get an embedding of the text. Then, you would use the embedding to query the vector index.

You are going to explore two scenarios:

In the first scenario, you will use existing question embeddings to find similar questions. In the second scenario, you will generate a new embedding for the user’s question to find similar questions and answers.

These scenarios will help you understand how to query the vector index to find similar questions and answers.

Finding similar questions

You can use the questions and answers vector indexes to find questions that are similar to each other.

A user views an existing question and wants to see similar questions.

The following Cypher query finds similar questions to the question "What are the most touristic countries in the world?".

Review the query before running it and observing the results.

MATCH (q:Question {text: "What are the most touristic countries in the world?"})

MATCH (node:Question)
SEARCH node IN (
    VECTOR INDEX questions
    FOR q.embedding
    LIMIT 6
) SCORE AS score

RETURN node.text, score

Breaking down the query, you can identify the following:

You can extend this query to return the answers to the most similar questions:

MATCH (q:Question {text: "What are the most touristic countries in the world?"})
MATCH (node:Question)
SEARCH node IN (
    VECTOR INDEX questions
    FOR q.embedding
    LIMIT 6
) SCORE AS score
MATCH (node)-[:ANSWERED_BY]->(a)
RETURN a.text, score

The query uses the node and the ANSWERED_BY relationship to find the answers.

Run the query and observe the results. You will notice that the top answers returned are similar to the question. As you get further down the list, the similarity score decreases and so does the relevance of the answers.

Finding answers to a similar question

To improve the user’s experience when asking a new question, you could use the vector index to find similar questions and answers.

To achieve this, you need to generate an embedding for the user’s new question and use it to query the vector index.

You can generate a new embedding in Cypher using the ai.text.embed function:

ai.text.embed(
    resource,
    provider,
    configuration = {}
) :: VECTOR

You pass the text you want to embed as the first parameter.

You can use embedding models from different providers, such as OpenAI, Vertex AI, and Amazon Bedrock. Provider-specific details like, API keys, are passed in the configuration map.

For example, you can use the OpenAI provider to generate an embedding by passing the API key as token and model in the configuration map:

WITH ai.text.embed(
    "Test",
    "OpenAI",
    { token: "sk-...", model: "text-embedding-ada-002" }
) AS embedding
RETURN toFloatList(embedding)

You can incorporate the embedding into your query to find similar questions:

WITH ai.text.embed(
    "What are good open source projects",
    "OpenAI",
    { token: "sk-...", model: "text-embedding-ada-002" }
) AS userEmbedding

MATCH (node:Question)
SEARCH node IN (
    VECTOR INDEX questions
    FOR userEmbedding
    LIMIT 6
) SCORE AS score
RETURN node.text, score

This query creates an embedding using ai.text.embed and then uses that embedding to query the questions vector index.

Try changing the text and observe the results.

Can you modify this query to work the same as the previous query and return the answers to the most similar questions?